# http://git.salome-platform.org/gitweb/

# Contributor: Xyne

_gitname='MED_SRC'
_gitbranch='V6_main'
pkgname=salome-med-git
pkgver=20130324
pkgrel=1
pkgdesc="generic platform for Pre and Post-Processing for numerical simulation (MED Module)"
url="http://www.salome-platform.org"
depends=('salome-kernel')
makedepends=('git' 'doxygen' 'python2-sphinx' 'python-docutils')
arch=('i686' 'x86_64')
conflicts=('salome-med')
provides=('salome-med')
license=('LGPL')
source=("git://git.salome-platform.org/$_gitname.git#branch=$_gitbranch")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"
  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_gitname"
  patch -p0 -t -i "$srcdir/boost.patch"
}

build() {
  cd "$srcdir/$_gitname"
  export PYTHON=/usr/bin/python2
  export SPHINX=/usr/bin/sphinx-build2
  export KERNEL_ROOT_DIR=/usr

  ./build_configure
  ./configure \
    --prefix=/usr \
    --with-python-site=/usr/lib/python2.7

  make
}

package() {
  cd "$srcdir/$_gitname"
  make DESTDIR="$pkgdir/" install
  # Add missing __init__.py file to ensure that the modules are detected.
  find "$pkgdir/usr/lib/python2.7/site-packages/salome" -type d -exec touch '{}'/__init__.py \;
}

# vim:set ts=2 sw=2 et: